MIDI on the SAM Coupé

Hi, I've been looking at 8-bit micro's recently and stumbled accross the SAM Coupé, which has some astounding capabilities.

I was particularly interested in the MIDI out. Luckly SIM Coupé lets you set midi out to the host computers MIDI player so it was just a matter of outing some bytes to port 253 to get it working and since GM is well documented (e.g. https://cmtext.indiana.edu/MIDI/chapter3_channel_voice_messages.php) I soon got a quick MIDI player working (below for example is a BASIC programme which loops through all MIDI instruments and percussion).

My question is mainly wandering how much MIDI out has ever been used in games/demos? For example if people would have gotten a Roland SC-55 or similar and used the SAM Coupé as a MIDI machine. I see there was at least one MIDI sequencer but not much more than that.

   20 REM Standard Instruments
   30 FOR t=0 TO 127
   40 PRINT "Instrument ";t
   50 midinst 0,t
   60 midplay 0,60
   70 FOR i=1 TO 500: NEXT i
   80 midstop 0,60
   90 FOR i=1 TO 250: NEXT i
  100 NEXT t
  110 midkill 0
  120 REM Percussion
  130 FOR t=33 TO 81
  140 PRINT "Percussion ";t
  150 midplay 9,t
  160 FOR i=1 TO 500: NEXT i
  170 midstop 9,t
  180 FOR i=1 TO 250: NEXT i
  190 NEXT t
  200 midkill 9
  220 STOP
  230 REM Change Instrument (Channel, Instrument)
  240 DEF PROC midinst c,i
  250 OUT 253,&c0+c
  260 OUT 253,i
  270 END PROC
  280 REM Play Note (Channel, Note, Velocity=127)
  290 DEF PROC midplay c,t,v
  300 DEFAULT v=127
  310 OUT 253,&90+c
  320 OUT 253,t
  330 OUT 253,v
  340 END PROC
  350 REM Release Note (Channel, Note, Velocity=64)
  360 DEF PROC midstop c,t,v
  370 DEFAULT v=64
  380 OUT 253,&80+c
  390 OUT 253,t
  400 OUT 253,v
  410 END PROC
  420 REM Silence Channel (Channel)
  430 DEF PROC midkill c
  440 OUT 253,&b0+c
  450 OUT 253,123
  460 OUT 253,0
  470 END PROC

Apart from the midi sequencer, I don't know about anything, but here are my attempts:


The SC-55 was $795 in 1991 (according to YouTube) which was approx £400 which is twice the price of the SAM Coupé. The market would have been tiny. 

Back in the day I did connect my mum’s synth keyboard, used the midi sequencer and tracked one or two sheet music tunes, but that was all. 

Antony: Thanks for those links to your player. I'd had a look at the .mid format and it is a relatively simple format so I was thinking of trying to make a player too. I doubt it'd be as good as yours but it's the sort of thing that's fun to play with.

Stefan: You're right, the SC-55 was a pretty high end of the market example but there also more affordable options, including synth keyboards.

It's a shame more wasn't made of it really. Native MIDI in/out was one of the few things that helped the Atari ST stand up against the Amiga after all. Though maybe "it's a shame more wasn't made of it" is the story of the SAM Coupé.